La résolution d'adresses avec DNS

Dans ce tutoriel, nous allons apprendre à utiliser le service DNS (Domaine Name System), pour retrouver une adresse IP à partir d'un nom de machine et inversement. Ce tutoriel est donc en deux parties: l'une pour expliquer comment retrouver l'adresse IP à partir d'un nom de machine, et l'autre pour faire l'inverse :o)

Ici, comme pour la leçon précédente sur le PING, nous n'avons pas besoin du contrôle Winsock, car nous allons utiliser les fonctions internes des librairies DLL de Windows.

Article lu fois.

L'auteur

Alexandre Lokchine

L'article

Publié le 11 janvier 2003 - Mis à jour le 5 janvier 2013

1. Retrouver l'adresse IP à partir du nom de la machine▲

Lancez un projet VB.
Ajoutez-y un module standard (qui se nomme module1.bas par défaut)
On y place le code suivant:

Cacher/Afficher le codeSélectionnez

Option Explicit
'Déclaration des constantes
Public Const IP_SUCCESS As Long = 0
Public Const MAX_WSADescription As Long = 256
Public Const MAX_WSASYSStatus As Long = 128
Public Const WS_VERSION_REQD As Long = &H101
Public Const WS_VERSION_MAJOR As Long = WS_VERSION_REQD \ &H100 And &HFF&
Public Const WS_VERSION_MINOR As Long = WS_VERSION_REQD And &HFF&
Public Const MIN_SOCKETS_REQD As Long = 1
Public Const SOCKET_ERROR As Long = -1
'Déclaration du type de données Winsock
Public Type WSADATA
wVersion As Integer
wHighVersion As Integer
szDescription(0 To MAX_WSADescription) As Byte
szSystemStatus(0 To MAX_WSASYSStatus) As Byte
wMaxSockets As Long
wMaxUDPDG As Long
dwVendorInfo As Long
End Type
'La fonction de résolutions d'adresses DNS appellée
'GetHostByName fait partie de la librairie Wsock32.dll
Private Declare Function gethostbyname Lib "wsock32" _
(ByVal hostname As String) As Long
'declaration des procedures auxilliares
Private Declare Sub CopyMemory Lib "kernel32" _
Alias "RtlMoveMemory" _
(xDest As Any, _
xSource As Any, _
ByVal nbytes As Long)
Private Declare Function lstrlenA Lib "kernel32" _
(lpString As Any) As Long
Public Declare Function WSAStartup Lib "wsock32" _
(ByVal wVersionRequired As Long, _
lpWSADATA As WSADATA) As Long

'Procedure de nettoyage des sockets
Public Declare Function WSACleanup Lib "wsock32" () As Long
'Routine d'initialisation du socket
Public Function SocketsInitialize() As Boolean
     Dim WSAD As WSADATA
     Dim success As Long

     SocketsInitialize = WSAStartup(WS_VERSION_REQD, WSAD) = IP_SUCCESS

End Function
'routine de nettoyage du socket retournant une msg d'erreur si 
'necessaire
Public Sub SocketsCleanup()
     If WSACleanup() <> 0 Then
     MsgBox "Une erreur à eu lieu lors de la fermeture.", vbExclamation
     End If
End Sub
'Cette fonction est en faite celle qu'on va appeller à chaque fois pour 
'résoudre un nom (passé en tant que String) et qui va nous retourner 
'une adresse IP (en String également)
Public Function GetIPFromHostName(ByVal sHostName As String) As String
'Conversion du nom d'hote en adresse IP
     Dim nbytes As Long
     Dim ptrHosent As Long 
     Dim ptrName As Long 
     Dim ptrAddress As Long 
     Dim ptrIPAddress As Long
     Dim sAddress As String

     sAddress = Space$(4)
     ptrHosent = gethostbyname(sHostName & vbNullChar)
     If ptrHosent <> 0 Then
'la fonction gethostbyname nous retourne un POINTEUR vers la structure 
'HOSENT en mémoire. On va recopier l'adresse IP en mémoire, qui 'commence 12 octets après le début de la structure

     ptrAddress = ptrHosent + 12

'get the IP address
     CopyMemory ptrAddress, ByVal ptrAddress, 4
     CopyMemory ptrIPAddress, ByVal ptrAddress, 4
     CopyMemory ByVal sAddress, ByVal ptrIPAddress, 4
     GetIPFromHostName = IPToText(sAddress)
     End If
End Function
'Cette fonction sert à transformer la structure retrouvée d'une adresse 
'IP (char x 4) en String du type "123.123.123.123"
Private Function IPToText(ByVal IPAddress As String) As String
     IPToText = CStr(Asc(IPAddress)) & "." & _
     CStr(Asc(Mid$(IPAddress, 2, 1))) & "." & _
     CStr(Asc(Mid$(IPAddress, 3, 1))) & "." & _
     CStr(Asc(Mid$(IPAddress, 4, 1)))

End Function
'----------fin du code module

OK. Maintenant, ajoutez un formulaire. Mettez-y deux champs de texte (Text1 et Text2) et un bouton de commande (Command1). Disposez-le comme suit et mettez la propriété Enabled de Text2 à False

Image non disponible

Ensuite, c'est tout simple...

Cacher/Afficher le codeSélectionnez

1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.

Private Sub Command1_Click() 
     Dim sHostName As String

     If SocketsInitialize() Then 'si socket initialisé avec succès

          'on appelle notre fonction
          sHostName = Text1.Text
          Text2.Text = GetIPFromHostName(sHostName)

          SocketsCleanup 'on nettoie le bazar...

     Else 'GROS pb système (DLL absente, corrompue etc...)

          MsgBox "Windows Sockets for 32 bit Windows " & _
          "ne répond pas. Vérifiez votre installation."

     End If
End Sub

Voilà, c'est tout. Tapez un nom de machine (e.g. w3.org) dans Text1 et cliquez sur le bouton. L'adresse IP s'affichera alors.

Image non disponible

Télécharger le projet d'application (Zip)

2. Retrouver le nom de la machine à partir de l'adresse IP▲

L'opération inverse, à savoir retrouver un nom de machine à partir de l'adresse IP, est légèrement plus compliquée, mais repose néanmoins sur les mêmes principes:

Créez un projet VB et ajoutez-y un module standard.
Le module reçoit le code suivant:

Cacher/Afficher le codeSélectionnez

1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
39.
40.
41.
42.
43.
44.
45.
46.
47.
48.
49.
50.
51.
52.
53.
54.
55.
56.
57.
58.
59.
60.
61.
62.
63.
64.
65.
66.
67.
68.
69.
70.
71.
72.
73.
74.
75.
76.
77.
78.
79.
80.
81.
82.
83.
84.
85.
86.
87.
88.
89.
90.
91.
92.
93.
94.
95.
96.
97.
98.
99.
100.
101.
102.
103.
104.
105.
106.
107.
108.
109.
110.
111.
112.
113.
114.
115.
116.
117.
118.
119.
120.
121.
122.
123.
124.
125.
126.
127.
128.
129.
130.
131.
132.
133.
134.
135.
136.
137.
138.
139.

Option Explicit
Private Const WSADescription_Len As Long = 256
Private Const WSASYS_Status_Len As Long = 128
Private Const WS_VERSION_REQD As Long = &H101
Private Const IP_SUCCESS As Long = 0
Private Const SOCKET_ERROR As Long = -1
Private Const AF_INET As Long = 2




Private Type WSADATA
  wVersion As Integer
  wHighVersion As Integer
  szDescription(0 To WSADescription_Len) As Byte
  szSystemStatus(0 To WSASYS_Status_Len) As Byte
  imaxsockets As Integer
  imaxudp As Integer
  lpszvenderinfo As Long
End Type




Private Declare Function WSAStartup Lib "wsock32" _
  (ByVal VersionReq As Long, _
   WSADataReturn As WSADATA) As Long
  
Private Declare Function WSACleanup Lib "wsock32" () As Long




Private Declare Function inet_addr Lib "wsock32" _
  (ByVal s As String) As Long




Private Declare Function gethostbyaddr Lib "wsock32" _
  (haddr As Long, _
   ByVal hnlen As Long, _
   ByVal addrtype As Long) As Long




Private Declare Sub CopyMemory Lib "kernel32" _
   Alias "RtlMoveMemory" _
  (xDest As Any, _
   xSource As Any, _
   ByVal nbytes As Long)
   
Private Declare Function lstrlen Lib "kernel32" _
   Alias "lstrlenA" _
  (lpString As Any) As Long
  
  
Public Function SocketsInitialize() As Boolean




   Dim WSAD As WSADATA
   
   SocketsInitialize = WSAStartup(WS_VERSION_REQD, WSAD) = IP_SUCCESS
    
End Function








Public Sub SocketsCleanup()
   
   If WSACleanup() <> 0 Then
       MsgBox "Une erreur a eu lieu lors de la fermeture.", vbExclamation
   End If
    
End Sub








Public Function GetHostNameFromIP(ByVal sAddress As String) As String




   Dim ptrHosent As Long
   Dim hAddress As Long
   Dim nbytes As Long
   
   If SocketsInitialize() Then




     'conversion du string IP en structure long

      hAddress = inet_addr(sAddress)
      
      If hAddress <> SOCKET_ERROR Then
         
        'pointeur vers la structure HOSTENT
         ptrHosent = gethostbyaddr(hAddress, 4, AF_INET)
   
         If ptrHosent <> 0 Then
         
           'obtention du nom d'hote
            CopyMemory ptrHosent, ByVal ptrHosent, 4
            nbytes = lstrlen(ByVal ptrHosent)
         
            If nbytes > 0 Then
               sAddress = Space$(nbytes)
               CopyMemory ByVal sAddress, ByVal ptrHosent, nbytes
               GetHostNameFromIP = sAddress
            End If
         
         Else: MsgBox "Appel de gethostbyaddr échoué."
         End If 'If ptrHosent
      
      SocketsCleanup
      
      Else: MsgBox "Cette chaîne n'est pas une adresse IP valide."
      End If 'If hAddress
   
   Else: MsgBox "Échec de l'initialisation du socket."
   End If  'If SocketsInitialize
      
End Function
'--fin du code module

Ensuite, créez un formulaire comme précédemment (Text1, Text2 et Command1). Ensuite, le petit bout de code qui suit suffit pour appeler la fonction:

Cacher/Afficher le codeSélectionnez

1.
2.
3.
4.

Private Sub Command1_Click() 
     Text2.Text = GetHostNameFromIP(Text1.Text)

End Sub

C'est fini... On peut faire une résolution...

Image non disponible

Télécharger le projet d'application (Zip)

Bon courage et bon développement,

Grafikm_fr

Copyright © 2003 Alexandre Lokchine. Aucune reproduction, même partielle, ne peut être faite de ce site ni de l'ensemble de son contenu : textes, documents, images, etc. sans l'autorisation expresse de l'auteur. Sinon vous encourez selon la loi jusqu'à trois ans de prison et jusqu'à 300 000 € de dommages et intérêts.